喵~~~~~的！！！多维引用白学了啊啊啊！！！（Excel函数集团）

这两天内心一直在徘徊的一句话就是……RT！

原因无它，就因为M365又出了新函数！

弄得本妖这会不知道是想暴走还是想撞墙~~~

============撞墙分隔线============

TEXTSPLIT

　　=TEXTSPLIT(字符串, 分列分隔符, 分行分隔符, 是否忽略空单元格, 填充值)

过去：

　　{=TRIM(MID(SUBSTITUTE(B6,"/",REPT(" ",99)),COLUMN(A:G)*99-98,99))}

现在：

　　=TEXTSPLIT(B6,"/")

撞墙指数：★★★☆☆

VSTACK / HSTACK

=VSTACK(数组1, 数组2,… , 数组254)

=HSTACK(数组1, 数组2,… , 数组254)

过去：

　　{=IF(N(OFFSET(A6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))),N(OFFSET($A$6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))),T(OFFSET($A$6,MOD(ROW(3:8),3),INT(ROW(3:8)/3)*5-5+COLUMN(A:D))))}

现在：

　　=VSTACK(B6:E8,G6:J8)

　　=HSTACK(B6:E8,G6:J8)

撞墙指数：★★★★★

TOROW / TOCOL

=TOROW(数组, 是否忽略空或错误, 先行后列或先列后行)

=TOCOL(数组, 是否忽略空或错误, 先行后列或先列后行)

 　　过去：

　　{=IF(N(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))),N(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))),T(OFFSET(B5,COLUMN(D:K)/4,MOD(COLUMN(D:K),4))))}

现在：

　　=TOROW(B6:E7)

　　=TOCOL(B6:E7)

撞墙指数：★★★★☆

WRAPROWS / WRAPCOLS

=WRAPROWS(一行或一列数组, 每行列数, 不足部分填充)

=WRAPCOLS(一行或一列数组, 每行列数, 不足部分填充)

过去：

　　{=IF(N(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))),N(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))),T(OFFSET(A6,,ROW(1:2)*4-4+COLUMN(A:D))))}

现在：

　　=WRAPROWS(B6:I6,4)

　　=WRAPCOLS(B6:I6,2)

撞墙指数：★★★★☆

TAKE / DROP

=TAKE(数组, 保留的前N行, 保留的前N列)

=DROP(数组, 去掉的前N行, 去掉的前N列)

过去：

　　{=OFFSET(B6,,,2,4)}

现在：

　　=TAKE(B6:E11,2)

　　=DROP(B6:E11,COUNTA(B6:B11)-2)

撞墙指数：★☆☆☆☆

CHOOSEROWS / CHOOSECOLS

=CHOOSEROWS(数组, 行数1, 行数2,…, 行数253)

=CHOOSECOLS(数组, 列数1, 列数2,…, 列数253)

过去：

　　{=IF(N(OFFSET(A5,{2;5},COLUMN(A:D))),N(OFFSET(A5,{2;5},COLUMN(A:D))),T(OFFSET(A5,{2;5},COLUMN(A:D))))}

现在：

　　=CHOOSEROWS(B6:E11,2,5)

　　=CHOOSECOLS(B6:E11,2,4)

撞墙指数：★★★★☆

 EXPAND

=EXPAND(数组, 扩展行数, 扩展列数, 填充的内容)

过去：

　　有过去吗？？？

现在：

　　=EXPAND(B6:E7,4,5,"")

撞墙指数：☆☆☆☆☆

另，还有两个函数TEXTBEFORE和TEXTAFTER，目前对汉字处理好像有BUG，以后再说。