Arduino 跷跷板(2016-01-04)

前言
这是参加社区活动，用赠送的 LilyPad 来做小实验，也体验了一把艺术的LilyPad！本来是申请 nano 的，不知道怎么的就出错啦，申请成 LilyPad 了，这个实验应该用 nano 比较合适，面包板比较方便接插（我还有更长的面包板哦 :D）。

接线图

代码

 1 // ----------------------------------------------------------------------------
 2 // seesaw.ino
 3 //
 4 // Created 2016-01-02
 5 // By seesea 
 6 //
 7 // 带渐暗灯效果的跷跷板
 8 // ----------------------------------------------------------------------------
 9 
10 // ------------------ 配置 ------------------
11 const char pinLED      = 5;                      // LED 的引脚
12 const char pinMagnet   = 6;                      // 电磁铁的引脚
13 const int  interval    = 700;                    // 跷跷板翻动的时间间隔，单位 ms
14 const int  initPwmLED  = 255;                    // LED 渐暗灯初始亮度
15 const char fadeTimes   = 50;                     // LED 渐暗灯在跷跷板翻动周期内渐变的级数（次数）
16 
17 // ------------------ 常量 ------------------
18 const int  deltaPwm    = initPwmLED / fadeTimes; // 根据 LED 初始亮度和渐变次数计算每一次渐变的 pwm 差值
19 const int  intervalLED = interval / fadeTimes;   // 根据 LED 初始亮度和渐变次数计算渐变的间隔
20 
21 // ---------------- 全局变量 ----------------
22 int pwmLED;                                      // 当前 LED 的 pwm 亮度值
23 
24 void setup()
25 {
26     pinMode(pinLED,    OUTPUT);
27     pinMode(pinMagnet, OUTPUT);
28 
29     fillLED();
30 }
31 
32 void loop()
33 {
34     // 渐暗 LED
35     fadeLED();
36 
37     // 主动端在上升的时候将 LED 设置为最亮
38     if (seesaw())
39         fillLED();
40 }
41 
42 // 跷跷板翻动函数
43 // 若跷跷板主动端开始上升，则返回 true，否则返回 false
44 bool seesaw()
45 {
46     static long ti = millis();
47     static byte seesawState = HIGH;
48 
49     if (millis() - ti < interval)
50         return false;
51 
52     digitalWrite(pinMagnet, seesawState);
53 
54     ti = millis();
55     seesawState = seesawState == HIGH ? LOW : HIGH;
56 
57     if (seesawState == LOW)
58        return true;
59 
60     return false;
61 }
62 
63 // 将 LED 置为初始亮度（最亮的值）
64 void fillLED()
65 {
66     pwmLED = initPwmLED;
67 }
68 
69 // 渐暗 LED
70 void fadeLED()
71 {
72     static long ti = millis();
73 
74     if (millis() - ti < intervalLED)
75         return;
76 
77     analogWrite(pinLED, pwmLED);
78 
79     ti = millis();
80     pwmLED -= deltaPwm;
81     if (pwmLED < 0)
82         pwmLED = 0;
83 }