s5pv210 重定位

makefile

final.bin: start.o led.o
    arm-linux-ld -Tlink.lds  -o start.elf $^     //link.lds为链接脚本，指定链接地址
    arm-linux-objcopy -O binary start.elf final.bin
    arm-linux-objdump -D start.elf > start_elf.dis
    
%.o : %.S
    arm-linux-gcc -o $@ $< -c -nostdlib

%.o : %.c
    arm-linux-gcc -o $@ $< -c -nostdlib

clean:
    rm *.o *.elf *.bin   -f

link.lds

SECTIONS
{
    . = 0xd0024000;   // . 表示程序自以为的地址，本行指定了链接地址
    
    .text : {
        start.o
        * (.text)    //表示start.o中的.text段放在前面，然后再把所有的文件的.text段放进来
    }
            
    .data : {
        * (.data)  　　//把所有的文件的.data段放进来
    }
    
    bss_start = .;  　　//把现在的地址赋给一个变量，供清bss段时使用
    .bss : {
        * (.bss)　　　　//把所有的文件的.bss段放进来
    }
    
    bss_end  = .;    //把现在的地址赋给一个变量，供清bss段时使用
}

start.S

#define WTCON        0xE2700000
#define SVC_STACK    0xd0037d80

.global _start
_start:

    // 第1步：关看门狗（向WTCON的bit5写入0即可）
    ldr r0, =WTCON
    ldr r1, =0x0
    str r1, [r0]
    
    // 第2步：设置SVC栈　　　　满减栈，满的意思是入栈先移动指针再填入数据，减的意思是栈从高到低用
    ldr sp, =SVC_STACK
    
    // 第3步：开/关icache
    mrc p15,0,r0,c1,c0,0;            // 读出cp15的c1到r0中  mrc和mcr是协处理器的相关汇编指令
    //bic r0, r0, #(1<<12)            // bit12 置0  关icache
    orr r0, r0, #(1<<12)            // bit12 置1  开icache
    mcr p15,0,r0,c1,c0,0;
    
    
    // 第4步：重定位
    adr r0, _start          // 将运行地址加载到r0    0xd0020010
    ldr r1, =_start         // 将链接地址加载到r0    0xd0024000
    
    ldr r2, =bss_start    // bss_start在链接脚本中定义
    cmp r0, r1            // 比较_start的运行时地址和链接地址是否相等
    beq clean_bss        // 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
                        // 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
                        // 重定位完成后继续执行clean_bss。

// 将运行地址开始所有的数据复制到链接地址开始的地方（即复制.text段和.data段），链接地址此时也在增加，当增加到bss段该开始的地方停止，并且开始清bss段
copy_loop:
    ldr r3, [r0], #4    // 源
    str r3, [r1], #4    // 目的   这两句代码就完成了4个字节内容的拷贝
    cmp r1, r2            // r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2
    bne copy_loop

// 清bss段，其实就是在链接地址处把bss段全部清零
clean_bss:
    ldr r0, =bss_start                    
    ldr r1, =bss_end
    cmp r0, r1                // 如果r0等于r1，说明bss段为空，直接下去
    beq run_on_dram            // 清除bss完之后的地址
    mov r2, #0
clear_loop:
    str r2, [r0], #4        // 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），
    cmp r0, r1                // 然后r0 = r0 + 4
    bne clear_loop

run_on_dram:    
    // 长跳转到led_blink开始第二阶段
    ldr pc, =led_blink                // ldr指令实现长跳转,跳转到完全复制过的链接地址处开始执行

    b .

led.c

#define GPJ0CON        0xE0200240
#define GPJ0DAT        0xE0200244
void delay(void)
{
    unsigned int cnt = 900000;
    while(cnt)
    {
        cnt--;
    }
    
}

void led_blink(void)
{
    unsigned int *p1 = (unsigned int *)GPJ0CON;
    unsigned int *p2 = (unsigned int *)GPJ0DAT;
    *p1 = 0x11111111;
    
    while(1)
    {
        *p2 = ~(1<<3);
        delay();
        *p2 = ~(1<<4);
        delay();
        *p2 = ~(1<<5);
        delay();
        
        
    }
    
}