Unity Phone模型 高光反射
β是反射光与相机方向之间的夹角
当β=0时，反射所有的光到摄像机,当β=1时没有反射光
反射光计算公式：
反射光 = 光线颜色 * 材质颜色 * ( 反射光强度 ^ 光泽度)
反射光强度计算公式：
反射光强度 = cosβ
r · v = |r| * |v| * cosβ
r 和 v取单位向量，所以
r · v = 1 * 1 * cosβ = cosβ
因为cosβ存在负数，所以要限制一下
反射光强度 = max(0,r · v) = max(cosβ)
反射光向量计算公式：
a = |l| * cosθ · n , n取单位向量
b = 2 * a = 2 * |l| * cosθ · n , l向量也单位向量
b = 2 * cosθ · n
b = 2 * (n · l) · n
因为 b = r + l，所以
r = b - l
r = 2 * (n · l) · n - l
最终反射光计算公式：
cosβ = r · v = (2 * (n · l) · n -l)
反射光强度 = 光线颜色 * 材质颜色 * ((2 * (n · l) · n -l) ^ 光泽度)
顶点Phone高光
点击查看代码
Shader "Unlit/008"
{
Properties
{
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(1,256)) = 5
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "UnityLightingCommon.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct v2f
{
// 声明用来存储顶点在裁剪空间下的坐标
float4 vertex: SV_POSITION;
// 用于传递计算出来的漫反射颜色
fixed3 color: Color;
};
// 计算顶点坐标从模型坐标系转换到裁剪面坐标系
v2f vert (appdata_base v)
{
v2f o;
// 将顶点坐标从模型空间转换到裁剪空间
o.vertex = UnityObjectToClipPos(v.vertex);
fixed3 worldPos = mul(unity_ObjectToWorld,v.vertex);
// 法线方向，把法线方向从模型空间转换到世界空间
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
// 光照方向，对于每个顶点来说，光的位置就是光的方向，因为光是平行光
// fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
fixed3 worldLight = UnityWorldSpaceLightDir(worldPos); // 使用Unity内置函数计算
// diffuse = 光线颜色 * 材质颜色 * max(0, n * l)
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));
// 计算发射光方向
// _WorldSpaceLightPos0的光是从顶点指向光的位置的。
// reflect函数是通过 光指向顶点的向量+法线 = 反射光
// 所以光的方向要取反
fixed3 reflectDir = normalize(reflect(-worldLight,worldNormal));
// 计算相机方向
// fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - UnityObjectToWorldDir(v.vertex).xyz);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos)); // 使用Unity内置函数计算
// 计算高光 反射光 = 光线颜色 * 材质颜色 * ( max(0,r · v) ^ 光泽度)
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
// 环境光
fixed3 ambinet = UNITY_LIGHTMODEL_AMBIENT.xyz;
o.color = diffuse + ambinet + specular;
return o;
}
// 计算每个像素的颜色值
fixed4 frag (v2f i) : SV_Target
{
return fixed4(i.color,1);
}
ENDCG
}
}
}
片元Phone高光
点击查看代码
Shader "Unlit/009"
{
Properties
{
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(1,256)) = 5
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "UnityLightingCommon.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct v2f
{
// 声明用来存储顶点在裁剪空间下的坐标
float4 vertex: SV_POSITION;
// 用于传递计算出来世界空间下的法线
fixed3 worldNormal: TEXCOORD0;
fixed3 worldPos: TEXCOORD1;
};
// 计算顶点坐标从模型坐标系转换到裁剪面坐标系
v2f vert (appdata_base v)
{
v2f o;
// 将顶点坐标从模型空间转换到裁剪空间
o.vertex = UnityObjectToClipPos(v.vertex);
// 法线方向，把法线方向从模型空间转换到世界空间
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldNormal = worldNormal;
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
return o;
}
// 计算每个像素的颜色值
fixed4 frag (v2f i) : SV_Target
{
// 环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// 光照方向，对于每个顶点来说，光的位置就是光的方向，因为光是平行光
// fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos); // 使用Unity内置函数计算
// diffuse = 光线颜色 * 材质颜色 * max(0, n * l)
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldLightDir,i.worldNormal));
// 计算发射光方向
// _WorldSpaceLightPos0的光是从顶点指向光的位置的。
// reflect函数是通过 光指向顶点的向量+法线 = 反射光
// 所以光的方向要取反
fixed3 reflectDir = normalize(reflect(-worldLightDir,i.worldNormal));
// 计算相机方向
// fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos)); // 使用Unity内置函数计算
// 计算高光 反射光 = 光线颜色 * 材质颜色 * ( max(0,r · v) ^ 光泽度)
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color,1);
}
ENDCG
}
}
}