【UnityShader】遮罩纹理

遮罩简单来讲就是允许我们保护一下区域免于修改，例如在模型的不同区域高光的强度不一样，表现出来的效果也不一样。

另一种是在地形材质时的制作时要混合多张图片，使用遮罩纹理可以控制如何混合这些纹理。

使用遮罩纹理的一般过程是：通过采样得到遮罩纹理的纹素质，然后使用某个通道的值来与某种表面属性相乘。

下面以使用r分量作掩码值乘以高光来控制高光反射。

Shader "Custom/Chapter7-MaskTexture"
{
   Properties
   {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap ("Normal Map", 2D) = "bump" {}
        _BumpScale ("Bump Scale", Float) = 1.0
        _SpecularMask("Specular Mask",2D) = "white"{}
        _SpecularScale("Specular Scale",Float) = 1.0
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
   }
   SubShader{
        pass{
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            sampler2D _BumpMap;
            sampler2D _SpecularMask;
            float _BumpScale;
            fixed4 _Specular;
            float _SpecularScale;
            float _Gloss;
            float4 _MainTex_ST;//纹理类型变量  三个纹理共用一种偏移平铺系数   

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 tangent:TANGENT;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos:SV_POSITION;
                float2 uv:TEXCOORD0;
                float3 lightDir:TEXCOORD1;
                float3 viewDir:TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv.xy = v.texcoord*_MainTex_ST.xy+_MainTex_ST.zw;//计算偏移

                //变换到切线空间
                TANGENT_SPACE_ROTATION;
                o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
                o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

                return o;
            }

            fixed4 frag(v2f i):SV_Target{
                fixed3 tangentLightDir = normalize(i.lightDir);
                fixed3 tangentViewDir = normalize(i.viewDir);

                fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap,i.uv));//处理切线空间法线的变化
                tangentNormal.xy *=_BumpScale;
                tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                fixed3 albedo = tex2D(_MainTex,i.uv).rgb*_Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;

                fixed3 diffuse = _LightColor0.rgb*albedo*max(0,dot(tangentNormal,tangentLightDir));

                fixed3 halfDir = normalize(tangentLightDir+tangentViewDir);
                //计算遮罩纹理
                fixed specularMask = tex2D(_SpecularMask,i.uv).r*_SpecularScale;
                fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(max(0,dot(tangentNormal,halfDir)),_Gloss)*specularMask;

                return fixed4(diffuse+specular+ambient,1.0);

            }
            ENDCG
        }
   }
    FallBack "Diffuse"
}

其中使用了遮罩纹理的r分量来计算掩码值，进而控制高光反射的强度。

其中不仅是r，RGBA四个分量都可以用来存储不同的属性，从而达到更高更精细的模型效果。